#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "stones.inc"

light_source { <0, 25, 5> color <1,1,1>}


camera {
        location  <0,10,-15>
        look_at <0,3,0>
}

#declare unitsquare = polygon {
	5, <0,0>,<1,0>,<1,1>,<0,1>, <0,0>
	translate <-0.5,-0.5,0>
}

/* The slide */
object {
	unitsquare
	texture {
		pigment {
			image_map {gif "povsheet.gif" interpolate 2 filter all 1.0}
			translate <-0.5,-0.5,0>
		}
	}
	texture {
		pigment {
			onion scale 0.01 turbulence 0
			color_map {
				[0 color <1,1,1> filter 0.75]
				[0.1 color <1,1,1> filter 0.95]
				[1 color <1,1,1> filter 1]
			}
		}
	}
	texture {
		pigment {
			onion scale 0.71 turbulence 0
			color_map {
				[0 color <1,1,1> filter 1]
				[0.85 color <1,1,1> filter 1]
				[0.95 color <1,1,1> filter 0]
				[1 color <1,1,1> filter 0]
			}
		}
	}
	translate <0,0,0.5>
	translate <0,0,-5>
}
light_source { <0, 0, -5.4> color <1,1,0.75>}

/* Projector box, preventing stray light */
merge {
	object { unitsquare translate <0,0,0.5> rotate 90*y}
	object { unitsquare translate <0,0,0.5> rotate -90*y}
	object { unitsquare translate <0,0,0.5> rotate -180*y}
	object { unitsquare translate <0,0,0.5> rotate 90*x}
	object { unitsquare translate <0,0,0.5> rotate -90*x}
	pigment {Brown}
	translate <0,0,-5>
}

/* the projection sheet */
box { <-10,-10,10>,<10,9.5,11>
	pigment{White}
	finish{specular 0.45}
	normal {ripples turbulence 0.5 scale 4}
	rotate x*5
}

/* Back wall */
box { <-20,-20,13>,<20,20,14>
	pigment{colour <0.8,0.8,0.8>}
	finish{specular 0.2}
}

//sphere {<2,-2,0>,2 texture{Glass} interior{ior 1.33}}
//sphere {<-3,2,0>,2 pigment{White} finish{reflection 0.5}}

cylinder{<5.5,5.6,10.3>,<15,-2,6>,0.1 pigment{White}}